CY545

Chapter 20
Getting Your CY545 Running

Getting Your CY545 Running

The following checklist will simplify getting your CY545 up and running.

1. Connect pin 20 to ground and pins 31 & 40 to +5 volts.

2. Be sure RESET (pin 9) is high for at least 10 milliseconds after power stabilizes. The CY545 can be reset at any time.

3. Upon proper reset, all outputs should be at logic 1, and the CY545 should be testing the JOG signal (pin 6).

4. Observe the crystal frequence divided by 6 on ALE, pin 30.

The following steps may be used with the Parallel Command Interface.

5. Place the “+” command on the data bus, ASCII value 2Bh

D0 = 1 D1 = 1 D2 = 0 D3 = 1 D4 = 0 D5 = 1 D6 = 0 D7 = 0

6. Lower the IO_REQUEST line, pin 13.

7. Wait for the BUSY line to go low before bringing IO_REQUEST high again. BUSY is pin 15.

8. When IO_REQUEST is brought back high, BUSY will return high.

9. Wait for BUSY to return high, then place the carriage return code on the data bus, value 0Dh

D0 = 1 D1 = 0 D2 = 1 D3 = 1 D4 = 0 D5 = 0 D6 = 0 D7 = 0

10. Generate the IO_REQUEST handshake strobe again, interacting with the BUSY signal.

11. Upon completion of the above sequence, CCW (pin 2) will go low.

The following steps may be used with the Serial Command Interface.

12. Connect your serial port to the CY545 RxD and TxD signals, pins 10 and 11, with the proper voltage translation buffers.

13. Send two carriage return codes to adapt the CY545 baud rate. The CRT emulation program at the end of this section is useful for this purpose.

14. Send the command “+<cr>”.

15. The CCW signal (pin 2) will go from high to low.

16. Repeat the above command sequence with a “-<cr>” command. The ASCII code for “-” is 2Dh. The CCW signal will return high when this command is sent.

If you have successful parallel or serial communications ...

17. If you reach this point successfully, you are commanding the CY545, and should be able to enter any command and obtain the correct response.

18. Suggested sequences:

a. Try to toggle a User Bit signal using “B 0<cr>” and “B 16<cr>” for pin 21. Remember the single space between the command letter and parameter value.

b. Take 200 steps with the default parameters, using “G<cr>”

c. Change the stepping parameters, using the R, F, S, and N commands, then try stepping again.

d. Refer to examples in this manual for other command sequences.

19. After the initial checkout, use your own command sequences as required by the application. You may need to exercise the external memory interface, thumbwheel switch interface, or an external display.

BASIC Language CRT Emulation Program

The following BASIC language program emulates a CRT for direct serial communications with the CY545A. It starts by sending the two carriage returns to set the CY545 baud rate. It then sends the Mode command to enable the CTS/ signal. These are both done with CTS monitoring disabled. The host serial port id then reconfigured to enable the CTS monitoring function, and all other commands use CTS/. The program is a simple terminal emulator, which takes any command entered from the keyboard and sends it to the CY545, while also displaying any serial data sent by the CY545.

100 '                   BASIC Language
110 '                   CRT EMULATOR FOR CY545A
120 '                   Cybernetic Micro Systems, Inc.
130 '
140 '   This program configures the CY545A for serial commands,
150 '   by sending two carriage returns to set the adaptive
160 '   rate, then sending a Mode command to enable the Clear
170 '   To Send signal.  After this, the program redefines the
180 '   computer serial port to function with the CTS signal.
190 '   It then becomes a terminal emulator, waiting for keyboard
200 '   input, which it displays on the screen and sends to the
210 '   CY545A, while displaying all serial characters received
220 '   from the CY545A.
230 '
300 CLS
310 LF$=CHR$(10)  :  CR$=CHR$(13)  : NL$=CHR$(0)  : ES$=CHR$(27)
320 '
330 '   Open the COM1 serial port at 9600 baud, no parity
340 '   Note that CTS is disabled during this part
350 '
360 OPEN "COM1:9600,N,8,1,CS0,DS0,CD0" AS #1
370 '
380 '   Send two carriage returns to adapt the CY545A baud rate
390 '
400 PRINT #1,CR$;CR$
410 '
420 '   Send the Mode command to turn on the CY545A CTS signal
430 '
440 PRINT #1,"O 0A0h";CR$
450 FOR I% = 1 to 5000                  'Delay while Mode Command is sent
460 NEXT I%
470 '
480 '   Now reconfigure COM1 to use CTS
490 '
500 CLOSE #1
510 OPEN "COM1:9600,N,8,1,CS30000,DS0,CD0" AS #1
520 LOCATE 5,5,1
530 PRINT "Ready to Go!"
540 '
550 '   Open the screen for displays
560 '
570 OPEN "SCRN:" FOR OUTPUT AS #2
600 '
610 '   Check for keyboard input.  Display and send any
620 '   keys to COM port.  Stop when Escape key input
630 '
640 A$=INKEY$  :  IF A$=ES$ GOTO 930
650 IF A$<>" " THEN PRINT #1,A$;  :  PRINT #2,A$;
700 '
710 '
720 '   Check for any received data from COM port, and
730 '   display it, with line feeds filtered out.  Loop back
740 '   to check keyboard again when no more received data
750 '
760 WHILE NOT EOF(1)
770  J%=LOC(1)  :  B$=INPUT$(J%,#1)  :  LF%=0
780  LF%=INSTR(LF%+1,B$,LF$)
790  IF LF%>0 THEN MID$(B$,LF%,1)=NL$  :  GOTO 780
800  PRINT #2,B$;
810 WEND
820 GOTO 640
900 '
910 '   Exit program when Escape key is pressed
920 '
930 CLOSE #1  :  CLOSE #2
940 STOP

[Selection Guide]

Changes from CY545 to CY545A

Please note: the CY545 is obsolete.

The CY545 did not have Clear-to-Send ("CTS"). The CY545A implements CTS function on pin 27.

Changes from CY545A to CY545B

Added Features:

Please note: the CY545A is obsolete.

The CY545A did not allow direct commands during program execution, and entering such commands caused command fragmentation, or interleaving of the commands from the two sources. Immediate commands entered at any time during program execution will now be accepted between executing commands and will be correctly interpreted and executed by the CY545B.

The CY545B adaptive baud rate can now adapt up to 57,600 baud (@ 11 MHz). While this rate has always been available as a fixed baud rate, the CY545A was adaptively limited to 300 to 19,200 baud.

The CY545B binary mode now allows ASCII "/" prefix for indicating the complement of a bit function. The CY545A binary mode required the actual complementary numerical values for clearing the bits.

The CY545B changes the 5 millisecond time-out at the end of a motion. The time-out value is now determined by the FirstRate paramenter. Faster rates (higher values) will time out fatser than slow rates. This change affects repetitive single stepping, where a single step (N 1) command is embedded in a program loop. The CY545A, because of the fixed time-out could single step continuously at only 200 steps per second (@ 11 MHz), while the CY545B will allow single stepping at up to approximately 1500 steps per second.

The CY545B tests for a free data bus before writing to the HP Display. This will allow slow parallel devices time to get off the bus, and so avoid bus conflicts. The CY545A assumed that parallel devices writing to the bus would do so quickly.

Problems Fixed: